@echo off
:: win7.cmd OEM-866
:: Version: 3.0.1
setlocal
set "SCRIPT_DIR=%~dp0"
set "PS1=%SCRIPT_DIR%win7-prepare.ps1"
set "PS_EXE=%SystemRoot%\system32\WindowsPowerShell\v1.0\powershell.exe"

echo.
echo ============================================================
echo   GPER Win7 Prepare  3.0.1
echo   SHA-2 + .NET 4.8 + PowerShell 5.1
echo ============================================================
echo.

net session >nul 2>&1
if errorlevel 1 (
    echo [ERROR] Запусти от имени администратора.
    pause
    exit /b 1
)

echo [INFO] TLS 1.2 в реестре WinHttp/.NET
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\WinHttp" /v DefaultSecureProtocols /t REG_DWORD /d 2560 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Internet Settings\WinHttp" /v DefaultSecureProtocols /t REG_DWORD /d 2560 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\.NETFramework\v4.0.30319" /v SchUseStrongCrypto /t REG_DWORD /d 1 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Wow6432Node\Microsoft\.NETFramework\v4.0.30319" /v SchUseStrongCrypto /t REG_DWORD /d 1 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\.NETFramework\v4.0.30319" /v SystemDefaultTlsVersions /t REG_DWORD /d 1 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Wow6432Node\Microsoft\.NETFramework\v4.0.30319" /v SystemDefaultTlsVersions /t REG_DWORD /d 1 /f >nul 2>&1

if not exist "%PS1%" (
    echo [ERROR] Нет файла %PS1%
    echo         Положи win7-prepare.ps1 рядом с этим cmd.
    pause
    exit /b 1
)

echo [INFO] Запуск win7-prepare.ps1
"%PS_EXE%" -NoProfile -ExecutionPolicy Bypass -File "%PS1%"
set "ERR=%ERRORLEVEL%"
if not "%ERR%"=="0" (
    echo [ERROR] win7-prepare.ps1 код %ERR%
    pause
    exit /b %ERR%
)
endlocal
exit /b 0